ringtools/imy: fix duplicate definition of tdma_durations[] The bug was reported by Vadim Yanitskiy <fixeria@osmocom.org>, although the present fix is slightly different from the contributed patch: because main.c doesn't need this tdma_durations[] array at all, let's simply remove the reference to this array from main.c rather than turn it into an extern. I no longer remember my original thought flow that resulted (by mistake) in tdma_durations[] being multiply defined in main.c and durations.c. My intent might have been to define all globals in main.c and have the reference in durations.c be an extern - and I missed that extern - but without clear memory, I have no certainty. In any case, having this data array defined in the same module that fills it (durations.c) is sensible, so let's make it the new way.

#include "ns16550.h"

@ this module implements the elementary serial I/O operations

	.comm	uart_base,4,4

	.text
	.code	32
	.global	serial_out
serial_out:
	ldr	r1, =uart_base
	ldr	r2, [r1]
1:	ldrb	r3, [r2, #0x11]		@ Calypso UART non-std register SSR
	tst	r3, #0x01		@ Tx FIFO full flag
	bne	1b
	strb	r0, [r2, #NS16550_THR]
	bx	lr

	.global	serial_in_poll
serial_in_poll:
	ldr	r1, =uart_base
	ldr	r2, [r1]
	ldrb	r3, [r2, #NS16550_LSR]
	tst	r3, #NS16550_LSR_DR
	ldrneb	r0, [r2, #NS16550_RBR]
	mvneq	r0, #0
	bx	lr

	.global	serial_flush
serial_flush:
	ldr	r1, =uart_base
	ldr	r2, [r1]
1:	ldrb	r3, [r2, #NS16550_LSR]
	tst	r3, #NS16550_LSR_TEMP
	beq	1b
	bx	lr