--- /dev/null	Thu Jan 01 00:00:00 1970 +0000
+++ b/target-utils/env/iram.lds	Wed May 01 07:39:35 2013 +0000
@@ -0,0 +1,54 @@
+OUTPUT_FORMAT("elf32-littlearm", "elf32-littlearm", "elf32-littlearm")
+OUTPUT_ARCH(arm)
+ENTRY(_entry)
+SECTIONS
+{
+    /* code */
+    . = 0x800750;
+    .text : {
+        /* regular code */
+        *(.text*)
+        /* gcc voodoo */
+        *(.glue_7t) *(.glue_7) *(.vfp11_veneer) *(.v4_bx)
+        . = ALIGN(4);
+    }
+
+    /* read-only data */
+    . = ALIGN(4);
+    .rodata : {
+        *(.rodata*)
+    }
+
+    /* initialized data */
+    . = ALIGN(4);
+    .data : {
+        *(.data)
+    }
+    PROVIDE(edata = .);
+
+    /* uninitialized data */
+    .bss (NOLOAD) : {
+        . = ALIGN(4);
+        __bss_start = .;
+        *(.bss)
+    }
+    . = ALIGN(4);
+    __bss_end = .;
+    /* end of image */
+    _end = .;
+    PROVIDE(end = .);
+}
+
+/* a few absolute definitions */
+rom_vars = 0x800518;
+/* stack_bottom = 0x83FFFC; */
+
+/*
+ * stack_bottom will be set via the --defsym option to ld.
+ * Some programs have minimal IRAM requirements, so it would make more
+ * sense to set stack_bottom to 0x83FFFC, don't use the upper half of
+ * IRAM for anything, and make that program portable to Calypso Lite
+ * devices.  But for some other programs we might have some use for
+ * the larger IRAM of our full Calypso devices, in which case we would
+ * want to set stack_bottom to 0x87FFFC instead.
+ */